Вопросы

Вообщем пытался сделать систему личного транспорта, но что-то не катит, я думал сделать массив в котором буду сохранять созданные и загруженные авто из бд, сам массив UserVehId, и еще надеялся на то что бы не было путаницы из другими авто, не личными. Но в итоге ни чего не работает, вернее пару машин загружаються только после перезагрузки сервера.

new TOTALCARS;
enum cInfo
{
 	cId,
    cModel,
    cPlayer[MAX_PLAYER_NAME],
    cFuelType,
    cSpeed,
    Float:cFuel,
    Float:cX,
    Float:cY,
    Float:cZ,
    Float:cA,
    cHealth,
    cColor1,
    cColor2
}
new CarInfo[MAX_VEHICLES][cInfo];
new UserVehId[100];
stock LoadCarInfo() // Çàãðóçêà òðàíñïîðòà
{
    new Cache: result = mysql_query(dbHandle, "select * from `cars`");
    TOTALCARS = cache_get_row_count(dbHandle);
    for(new i = 0; i < TOTALCARS; i ++)
    {
        CarInfo[i+1][cId] = cache_get_row_int(i, 0, dbHandle);
        CarInfo[i+1][cModel] = cache_get_row_int(i, 1, dbHandle);
        cache_get_row(i, 2, CarInfo[i+1][cPlayer], dbHandle, 48);
        CarInfo[i+1][cFuelType] = cache_get_row_int(i, 3, dbHandle);
        CarInfo[i+1][cSpeed] = cache_get_row_int(i, 4, dbHandle);
        CarInfo[i+1][cFuel] = cache_get_row_float(i, 5, dbHandle);
        CarInfo[i+1][cX] = cache_get_row_float(i, 6, dbHandle);
        CarInfo[i+1][cY] = cache_get_row_float(i, 7, dbHandle);
        CarInfo[i+1][cZ] = cache_get_row_float(i, 8, dbHandle);
        CarInfo[i+1][cA] = cache_get_row_float(i, 9, dbHandle);
        CarInfo[i+1][cHealth] = cache_get_row_int(i, 10, dbHandle);
        CarInfo[i+1][cColor1] = cache_get_row_int(i, 11, dbHandle);
        CarInfo[i+1][cColor2] = cache_get_row_int(i, 12, dbHandle);
        UserVehId[i] = CreateVehicle(CarInfo[i+1][cModel], CarInfo[i+1][cX], CarInfo[i+1][cY], CarInfo[i+1][cZ], CarInfo[i+1][cA], CarInfo[i+1][cColor1], CarInfo[i+1][cColor2], -1);
    }
    cache_delete(result, dbHandle);
}
    
stock SaveCar(vehicleid) // Ñîõðàíåíèå òðàíñïîðòà
{
    new src[1500],query[1500];
    TOTALCARS = cache_get_row_count(dbHandle);
	format(query,sizeof(query),"UPDATE "TABLE_CARS" SET ");
	format(src,sizeof(src),"cModel=%i,",CarInfo[vehicleid][cModel]);
	strcat(query,src);
	format(src,sizeof(src),"cX=%.2f,",CarInfo[vehicleid][cX]);
	strcat(query,src);
	format(src,sizeof(src),"cY=%.2f,",CarInfo[vehicleid][cY]);
	strcat(query,src);
	format(src,sizeof(src),"cZ=%.2f,",CarInfo[vehicleid][cZ]);
	strcat(query,src);
	format(src,sizeof(src),"cA=%.2f,",CarInfo[vehicleid][cA]);
	strcat(query,src);
	format(src,sizeof(src),"cColor1=%i,",CarInfo[vehicleid][cColor1]);
	strcat(query,src);
	format(src,sizeof(src),"cColor2=%i,",CarInfo[vehicleid][cColor2]);
	strcat(query,src);
	format(src,sizeof(src),"cSpeed=%i,",CarInfo[vehicleid][cSpeed]);
	strcat(query,src);
	format(src,sizeof(src),"cFuel=%f,",CarInfo[vehicleid][cFuel]);
	strcat(query,src);
	format(src,sizeof(src),"cFuelType=%i,",CarInfo[vehicleid][cFuelType]);
	strcat(query,src);
	format(src,sizeof(src),"cHealth=%i,",CarInfo[vehicleid][cHealth]);
	strcat(query,src);
	format(src,sizeof(src),"cPlayer='%s'",CarInfo[vehicleid][cPlayer]);
	strcat(query,src,sizeof(query));
	mysql_function_query(dbHandle, query, false, "", "");
}                                 

Вот диалог покупки авто и его добавление в бд, и последующее его создание

case 18:
        {
            new Cache: result = mysql_query(dbHandle, "select * from `cars`");
    		TOTALCARS = cache_get_row_count(dbHandle);
            new string[256];
            new model = GetVehicleModel(GetPlayerVehicleID(playerid));
            new Float: p_x, Float: p_y, Float: p_z, Float: p_a; GetVehiclePos(GetPlayerVehicleID(playerid), p_x, p_y, p_z);
            GetVehicleZAngle(GetPlayerVehicleID(playerid), p_a);
            CarInfo[TOTALCARS][cModel] = model;
			CarInfo[TOTALCARS][cPlayer] = PlayerInfo[playerid][pName];
			CarInfo[TOTALCARS][cFuelType] = 95;
			CarInfo[TOTALCARS][cSpeed] = 134;
			CarInfo[TOTALCARS][cFuel] = 60.0;
			CarInfo[TOTALCARS][cX] = p_x+5;
			CarInfo[TOTALCARS][cY] = p_y;
			CarInfo[TOTALCARS][cZ] = p_z;
			CarInfo[TOTALCARS][cA] = p_a;
			CarInfo[TOTALCARS][cHealth] = 1000;
			CarInfo[TOTALCARS][cColor1] = 0;
			CarInfo[TOTALCARS][cColor2] = 0;
            if(!response)return RemovePlayerFromVehicle(playerid);
            format(string, sizeof(string), "insert into `cars` (`cModel`, `cPlayer`, `cFueltype`, `cSpeed`, `cFuel`, `cX`, `cY`, `cZ`, `cA`, `cHealth`, `cColor1`, `cColor2`) values (%i, %i, '%s', %i, %i, %.2f, %.2f, %.2f, %.2f, %.2f, %i, %i, %i)",
            CarInfo[TOTALCARS][cModel], PlayerInfo[playerid][pName], CarInfo[TOTALCARS][cFuelType], CarInfo[TOTALCARS][cSpeed], CarInfo[TOTALCARS][cFuel], CarInfo[TOTALCARS][cX], CarInfo[TOTALCARS][cY], CarInfo[TOTALCARS][cZ], CarInfo[TOTALCARS][cA], CarInfo[TOTALCARS][cHealth], CarInfo[TOTALCARS][cColor1], CarInfo[TOTALCARS][cColor2]);
            mysql_tquery(dbHandle, string);
            LoadLastCarInfo();
			UserVehId[TOTALCARS] = CreateVehicle(CarInfo[TOTALCARS][cModel], CarInfo[TOTALCARS][cX], CarInfo[TOTALCARS][cY], CarInfo[TOTALCARS][cZ], CarInfo[TOTALCARS][cA], CarInfo[TOTALCARS][cColor1], CarInfo[TOTALCARS][cColor2], -1);
            TOTALCARS++;
		}

И проверочная функция, работает ли вообще все это, когда игрок выходит из авто, то сохраняются координаты, и отправля.тся в бд

public OnPlayerExitVehicle(playerid, vehicleid)
{
    new Float: p_x, Float: p_y, Float: p_z, Float: p_a;
    new string[128];
    if(vehicleid >= UserVehId[0]/* && vehicleid <= UserVehId[TOTALCARS]*/)
    {
        for(new c=0; c<=TOTALCARS; c++)
		{
		    if(vehicleid==UserVehId[c])
		    {
				GetVehiclePos(vehicleid, p_x, p_y, p_z);
				GetVehicleZAngle(vehicleid, p_a);
				CarInfo[vehicleid][cX] = p_x;
				CarInfo[vehicleid][cY] = p_y;
				CarInfo[vehicleid][cZ] = p_z;
				CarInfo[vehicleid][cA] = p_a;
				new result[128];
				format(result,sizeof(result), "%i %i %i",CarInfo[vehicleid-1][cId], CarInfo[vehicleid][cId], CarInfo[UserVehId[vehicleid]][cId]);
				SendClientMessage(playerid, COLOR_GREEN, result);
				SaveCar(UserVehId[c]);
			}
		}
	}
	return true;
}

 

Поделиться сообщением


Ссылка на сообщение

2 ответа на этот вопрос

  • 0

А зачем вам лишний массив создавать? Если загрузка с бд есть и сохранение

Поделиться сообщением


Ссылка на сообщение
  • 0

@PhNst27, помню тоже лет этак 6 назад мучился насчет того, как написать систему транспортных средств. Много, конечно, мудрил. Но в конечном счете достиг чего-то более-менее для меня совершенного.

 

Спойлер

Опыт показал, что очень удобно иметь возможность управлять всеми транспортными средствами через базу данных. Под всеми я подразумеваю не только личный транспорт. Сюда относится и служебный (подработки), и фракционный, и транспорт под аренду. В общем, если на сервере появляется статический транспорт, то он обязательно должен быть и в базе данных (очевидно, что временный транспорт, например, созданный администратором для своих "покатушек" или витринный (при выборе транспорта в автосалоне) не должен сохраняться в базе данных). Для того, чтобы оперировать с разными типами транспорта (этот для фракции, тот кому-либо принадлежит), выделил отдельную переменную, в которую и записывал тип транспорта.

 

Если Вас заинтересует такой расклад, могу описать несколько подробнее, возможно, даже в отдельной теме. На нет и суда нет, как говорится.

 

Итак. Давайте для начала разберемся с Вашим двумерным массивом:

CarInfo[MAX_VEHICLES][cInfo]

Первый индекс массива (вместо MAX_VEHICLES) должен указывать на ID транспортного средства на сервере. Обратите внимание на выделенное слово. Дело в том, что своим вариантом Вы используете вторую ячейку как порядковый ID загружаемого транспорта. Но все же гораздо удобнее (для реализации всей системы) использовать ее как ID транспорта на сервере. Этот ID возвращают все функции, связанные с созданием транспортных средств:

Что касается перечисления cInfo. В нем присутствует такая переменная, как cID. Эта переменная должна хранить в себе ID транспортного средства в базе данных. Именно она поможет нам связать транспортное средство на сервере с транспортным средством в базе данных: ее мы будем использовать как ключ. Так, например, запрос в базу данных на удаление транспортного средства примет вид:

DELETE FROM vehicles WHERE cID = 1;
// vehicles - наименование таблицы, хранящей данные о транспортных средствах
// cID - наименование столбца с атрибутом AUTO_INCREMENT (по сути номер строки)

Для того, чтобы получить, например, модель транспортного средства, в которое садится игрок, можно использовать следующй код:

Спойлер

 


public OnPlayerEnterVehicle(playerid, vehicleid, ispassenger)
{
	// vehicleid - ID транспортного средства, в которое садится игрок
	
	new string[61+(-2+3)+1];
	format(string, sizeof string, "Вы садитесь в транспортное средство, ID модели которого - %d.", CarInfo[vehicleid][cModel]);
	SendClientMessage(playerid, -1, string);
	return 1;
}

 

В итоге, обобщив все сказанное, получим примерно такую функцию загрузки транспортных средств из базы данных:

Спойлер

stock LoadCarInfo()
{
	new Cache: result = mysql_query(dbHandle, "select * from `cars`");
	TOTALCARS = cache_get_row_count(dbHandle); // количество личных транспортных средств
	
	new vehicleid, model, Float:x, Float:y, Float:z, Float:a, color1, color2;
	
	for(new i = 0; i < TOTALCARS; i ++)
	{
		// загрузим основные данные для создания ТС во временные переменные
		model = cache_get_row_int(i, 1, dbHandle);
		x = cache_get_row_float(i, 6, dbHandle);
		y = cache_get_row_float(i, 7, dbHandle);
		z = cache_get_row_float(i, 8, dbHandle);
		a = cache_get_row_float(i, 9, dbHandle);
		color1 = cache_get_row_int(i, 11, dbHandle);
		color2 = cache_get_row_int(i, 12, dbHandle);		
		// создадим транспортное средство, чтобы сразу получить его ID на сервере
		vehicleid = CreateVehicle(model, x, y, z, a, color1, color2, -1);
		// начнем заполнять массив для нашего транспорта (его первый индекс эквивалентен ID ТС на сервере)
		CarInfo[vehicleid][cModel] = model;
		CarInfo[vehicleid][cX] = x;
		CarInfo[vehicleid][cY] = y;
		CarInfo[vehicleid][cZ] = z;
		CarInfo[vehicleid][cA] = a;
		CarInfo[vehicleid][cColor1] = color1;
		CarInfo[vehicleid][cColor2] = color2;		
		
		CarInfo[vehicleid][cId] = cache_get_row_int(i, 0, dbHandle);
		cache_get_row(i, 2, CarInfo[vehicleid][cPlayer], dbHandle, 48);
		CarInfo[vehicleid][cFuelType] = cache_get_row_int(i, 3, dbHandle);
		CarInfo[vehicleid][cSpeed] = cache_get_row_int(i, 4, dbHandle);
		CarInfo[vehicleid][cFuel] = cache_get_row_float(i, 5, dbHandle);
		CarInfo[vehicleid][cHealth] = cache_get_row_int(i, 10, dbHandle);
		
		// изменим, например, здоровье нашего транспорта в соответствии с cHealth
		SetVehicleHealth(vehicleid, CarInfo[vehicleid][cHealth]);
	}
	cache_delete(result, dbHandle);
}

 

 

Пусть участок кода заметно и раздулся, зато в будущем оперировать со всеми транспортными средствами будет проще. Также я бы настоятельно рекомендовал создать прототип функции CreateVehicle, который бы содержал весь необходимый набор параметров и установок для создаваемого транспорта. На всякий случай оставлю здесь пример, как это могло бы выглядеть (вырезка из моего мода).

Спойлер
Спойлер


#if defined _vehicle_object
	#endinput
#endif
#define _vehicle_object

stock CreateVehicleEx(
	modelid, Float:x, Float:y, Float:z, Float:a = 0.0, worldid = 0, interiorid = 0, color[2] = {-1, -1}, number[MAX_LENGTH_VEHICLE_NUMBER] = DEFAULT_VEHICLE_NUMBER,
	Float:fuel = -1.0, Float:maxfuel = -1.0, owner[MAX_PLAYER_NAME] = "none", sowner[MAX_PLAYER_NAME] = "none", adminid = -1, bool:save = false, playerid = -1, seatid = -1,
	e_VEHICLE_MEMBERS:type = VEHICLE_MEMBER_DEFAULT, bool:siren = false, bool:engine = false, bool:lights = false, e_VEHICLE_DOOR_STATE:doors = DOOR_OPENED, fracid = 0, rank = 0,
	bool:bonnet = false, bool:boot = false, bool:key = true, e_VEHICLE_WINDOW_STATE:windows = WINDOW_OPENED, price = 0, Float:health = 1000.0, bool:valuet = false
)
{
	if(COUNT_VEHICLES+1 >= MAX_VEHICLES){
		Log(log_main, ERROR, "[x] ѕревышен лимит транспортных средств. —оздание нового транспорта невозможно.");
		return 0;
	}

	if(!IsValidVehicleModel(modelid)){
		return 0;
	}

	if(color[0] == -1){
		color[0] = random(255);
		color[1] = random(255);
	}

	if(fuel == -1){
		fuel = maxfuel = g_vehicle_data[modelid-400][FUELMAX];
	}

	if(playerid != -1 && g_player[playerid][LOGIN] == false){
		playerid = -1;
	}

	if(adminid != -1 && g_player[playerid][LOGIN] == false){
		adminid = -1;
	}

	if(!IsValidModelSeat(modelid, seatid)){
		return 0;
	}

	new vehicleid = CreateVehicle(modelid, x, y, z, a, color[0], color[1], -1, _:siren);
	if(vehicleid == INVALID_VEHICLE_ID){
		return 0;
	}
	// =====

	g_vehicle[vehicleid][LOAD] = save;
	g_vehicle[vehicleid][MODEL] = modelid;
	g_vehicle[vehicleid][X] = x;
	g_vehicle[vehicleid][Y] = y;
	g_vehicle[vehicleid][Z] = z;
	g_vehicle[vehicleid][A] = a;
	g_vehicle[vehicleid][WORLD] = worldid;
	g_vehicle[vehicleid][INTERIOR] = interiorid;
	strcpy(g_vehicle[vehicleid][COLOR], color);
	strcpy(g_vehicle[vehicleid][NUMBER], number);
	g_vehicle[vehicleid][FUEL] = fuel;
	g_vehicle[vehicleid][MAXFUEL] = maxfuel;
	strcpy(g_vehicle[vehicleid][OWNER], owner);
	strcpy(g_vehicle[vehicleid][SOWNER], sowner);
	g_vehicle[vehicleid][ADMINID] = adminid;
	g_vehicle[vehicleid][SAVE] = save;
	g_vehicle[vehicleid][TYPE] = type;
	g_vehicle[vehicleid][SIREN] = siren;
	
	g_vehicle[vehicleid][ENGINE] = engine;
	g_vehicle[vehicleid][LIGHTS] = lights;
	g_vehicle[vehicleid][DOORS] = doors;
	g_vehicle[vehicleid][BONNET] = bonnet;
	g_vehicle[vehicleid][BOOT] = boot;
	g_vehicle[vehicleid][WINDOWS] = windows;
	g_vehicle[vehicleid][KEY] = key;

	SetVehicleParamsEx(vehicleid, engine, lights, false, doors, bonnet, boot, false);
	SetVehicleDoorState(vehicleid, VEHICLE_DOOR_ALL, doors);
	SetVehicleWindowState(vehicleid, VEHICLE_DOOR_ALL, windows);

	if(worldid != 0){
		SetVehicleVirtualWorldEx(vehicleid, worldid);
	}
	
	if(interiorid != 0){
		LinkVehicleToInteriorEx(vehicleid, interiorid);
	}
	if(playerid != -1 && seatid != -1){
		PutPlayerInVehicle(playerid, vehicleid, seatid);
	}

	if(save == true){

		new mysqlid;

		if(type & VEHICLE_MEMBER_DEFAULT){
			mysql_format_query(dbMain, insert_vehicle_default, g_vehicle[vehicleid][LOAD], _:type, modelid, x, y, z, a, worldid, interiorid, color[0], color[1], number, fuel, maxfuel, health, doors, key);
			mysqlid = cache_insert_id();

			if(mysqlid == 0){
				return 0;
			}
		}
		
		if(type & VEHICLE_MEMBER_PLAYERS){
			mysql_format_query(dbMain, insert_vehicle_players, mysqlid, owner, sowner, price, valuet);
		}

		if(type & VEHICLE_MEMBER_RENTS){
			mysql_format_query(dbMain, insert_vehicle_rents, mysqlid, price, valuet);
		}

		if(type & VEHICLE_MEMBER_FRACS){
			mysql_format_query(dbMain, insert_vehicle_fracs, mysqlid, fracid, rank, siren);
		}

		g_vehicle[vehicleid][ID] = (mysqlid > 0) ? (mysqlid) : (INVALID_VEHICLE_ID);
	}

	if(adminid != -1){
		CreateLogAdmin(playerid, LOG_TYPE_INFO, "создание транспорта (model - %d, mysqlid - %d)", modelid, g_vehicle[vehicleid][ID]);
	}

	COUNT_VEHICLES++;

	return 1;
}

 

Спойлер


#if defined _vehicle_load
	#endinput
#endif
#define _vehicle_load

enum e_VEHICLE_LOAD (<<= 1)
{
	VEHICLE_LOAD_DEFAULT = 1,
	VEHICLE_LOAD_PLAYER,
	VEHICLE_LOAD_RENT,
	VEHICLE_LOAD_FRAC,

	VEHICLE_LOAD_ALL = VEHICLE_LOAD_DEFAULT | VEHICLE_LOAD_PLAYER | VEHICLE_LOAD_RENT | VEHICLE_LOAD_FRAC
}

stock OnVehiclesLoad(vehicleid, e_VEHICLE_LOAD:stateid = VEHICLE_LOAD_ALL)
{
	if(stateid & VEHICLE_LOAD_DEFAULT){
		mysql_tquery(dbMain, load_vehicles_default, "LoadDefaultVehicles", "");
	}

	if(stateid & VEHICLE_LOAD_PLAYER){
		mysql_tquery(dbMain, load_vehicles_players, "LoadPlayerVehicles", "");
	}

	if(stateid & VEHICLE_LOAD_RENT){
		mysql_tquery(dbMain, load_vehicles_rents, "LoadRentVehicles", "");
	}

	if(stateid & VEHICLE_LOAD_FRAC){
		mysql_tquery(dbMain, load_vehicles_fracs, "LoadFracVehicles", "");
	}

	return 1;
}

forward LoadDefaultVehicles();
public LoadDefaultVehicles()
{
	new count = cache_num_rows();

	if(count == 0){
		print("[x] “ранспортные средства (default) не были загружены: данные в базе отсутствуют.");
		return 0;
	}

	if(count+COUNT_VEHICLES >= MAX_VEHICLES){
		print("[x] “ранспортные средства (default) не были загружены: превышен лимит транспортных средств.");
		return 0;
	}

	new time = GetTickCount(),
		type, model,
		Float:x, Float:y, Float:z, Float:a,
		worldid, interiorid, color[2], number[MAX_LENGTH_VEHICLE_NUMBER],
		Float:fuel, Float:maxfuel, Float:health, e_VEHICLE_DOOR_STATE:doors, bool:key
	;

	for(new i = 0; i < count; i++)
	{
		cache_get_value_name_int(i, "type", type);
		cache_get_value_name_int(i, "model", model);

		cache_get_value_name_float(i, "x", x);
		cache_get_value_name_float(i, "y", y);
		cache_get_value_name_float(i, "z", z);
		cache_get_value_name_float(i, "a", a);
		cache_get_value_name_int(i, "world", worldid);
		cache_get_value_name_int(i, "interior", interiorid);

		cache_get_value_name_int(i, "color1", color[0]);
		cache_get_value_name_int(i, "color2", color[1]);

		cache_get_value_name(i, "number", number, MAX_LENGTH_VEHICLE_NUMBER);

		cache_get_value_name_float(i, "fuel", fuel);
		cache_get_value_name_float(i, "maxfuel", maxfuel);
		cache_get_value_name_float(i, "health", health);

		cache_get_value_name_int(i, "doors", doors);
		cache_get_value_name_int(i, "key", key);

		CreateVehicleEx
		(
			.modelid = model, .x = x, .y = y, .z = z, .a = a, .worldid = worldid, .interiorid = interiorid,
			.color = color, .number = number, .fuel = fuel, .maxfuel = maxfuel, .health = health, .doors = doors, .key = key
		);
	}

	Log(log_load, INFO, "[ї] “ранспортные средства default в количестве %dшт. успешно загружены за %d мс.", count, GetTickCount()-time);
	return 1;
}

forward LoadPlayerVehicles();
public LoadPlayerVehicles()
{
	// some code
	return 1;
}

forward LoadRentVehicles();
public LoadRentVehicles()
{
	// some code
	return 1;
}

forward LoadFracVehicles();
public LoadFracVehicles()
{
	// some code
	return 1;
}

 

 

Ну, и осталось немного поправить сохранение транспорта (всего лишь добавлением ключа поиска):

Спойлер

stock SaveCar(vehicleid)
{
	new src[1500], query[1500];
	// TOTALCARS = cache_get_row_count(dbHandle); - зачем эта строка была здесь?
	format(query,sizeof(query),"UPDATE "TABLE_CARS" SET ");
	format(src,sizeof(src),"cModel=%i,",CarInfo[vehicleid][cModel]);
	strcat(query,src);
	format(src,sizeof(src),"cX=%.2f,",CarInfo[vehicleid][cX]);
	strcat(query,src);
	format(src,sizeof(src),"cY=%.2f,",CarInfo[vehicleid][cY]);
	strcat(query,src);
	format(src,sizeof(src),"cZ=%.2f,",CarInfo[vehicleid][cZ]);
	strcat(query,src);
	format(src,sizeof(src),"cA=%.2f,",CarInfo[vehicleid][cA]);
	strcat(query,src);
	format(src,sizeof(src),"cColor1=%i,",CarInfo[vehicleid][cColor1]);
	strcat(query,src);
	format(src,sizeof(src),"cColor2=%i,",CarInfo[vehicleid][cColor2]);
	strcat(query,src);
	format(src,sizeof(src),"cSpeed=%i,",CarInfo[vehicleid][cSpeed]);
	strcat(query,src);
	format(src,sizeof(src),"cFuel=%f,",CarInfo[vehicleid][cFuel]);
	strcat(query,src);
	format(src,sizeof(src),"cFuelType=%i,",CarInfo[vehicleid][cFuelType]);
	strcat(query,src);
	format(src,sizeof(src),"cHealth=%i,",CarInfo[vehicleid][cHealth]);
	strcat(query,src);
	format(src,sizeof(src),"cPlayer='%s' ",CarInfo[vehicleid][cPlayer]);
	strcat(query,src,sizeof(query));
	format(src,sizeof(src),"WHERE cID='%d' LIMIT 1",CarInfo[vehicleid][cID]);
	strcat(query,src,sizeof(query));	
	mysql_function_query(dbHandle, query, false, "", "");
}

 

 

В конце хотел бы обратить внимание на два аспекта.

  1. В своем ответе я всегда употреблял слово транспорт (vehicle), но не машина (car). Дело в том, что у игроков во владении может быть не только машина, но и велосипед, катер, вертолет. Поэтому не есть правильно обобщать все это в машину. Я бы на вашем месте все Car переименовал в Vehicle.
  2. Гораздо лучше иметь 20 функций, каждая из которых сохраняет какой-то один параметр, нежели сохранять 20 параметров в одной функции. Почему? Существует огромное количество параметров, которые меняться не будут вообще, либо будут подвергаться изменениям крайне редко. Взять, например, в Вашей функции сохранения вот это: "cModel=%i". Хотите сказать модель будет изменяться? Да и незачем тратить ресурсы на сохранение того, что не изменилось.

Поделиться сообщением


Ссылка на сообщение
Гость
Эта тема закрыта для публикации ответов.
  • Последние посетители   0 пользователей онлайн

    Ни одного зарегистрированного пользователя не просматривает данную страницу

  • Похожий контент

    • Mister Odin
      От Mister Odin
       
      new
       g_teleport_list[39][E_TELEPORT_LIST] = {  {"Спавн пгт.Батырево", 1802.3612, 2508.4824, 15.8887},  {"Спавн г.Арзамас", -113.5887, 977.7222, 12.0346},     {"Спавн г.Южный", 2744.2770, -2446.7246, 21.8988},     {"Центральный банк", 1852.020385,2040.791381,15.892713},  {"Рублёвка", -837.7783, 888.6161, 12.7232},  {"Казино", 1332.4252, 2358.7014, 17.6641},  {"Битва за контейнеры", 614.5167, 1722.3566, 12.0709},  {"Автосалон низкого класса", 2493.9616, -722.9544, 12.3315},  {"Автосалон среднего класса", 1407.7449, 455.4801, 13.1630},  {"Автосалон высокого класса", -14.0637, 2614.5664, 10.9892},   {"Мотосалон Harley Davidson", 785.720153, 750.465087, 12.000024},  {"Автошкола", 1909.174438,2227.679687,15.708162},  {"Военкомат", 1916.778564,2302.411376,15.574637},  {"Правительство области", -139.140975,593.789611,12.145712},  {"Отдел полиции №1 (ГИБДД)", 1906.805786,-2234.382812,11.257631},  {"Отдел полиции №2 (УМВД)", 2581.309326,-2416.139892,21.960090},  {"Отдел ФСБ", 1823.904663,2095.636718,15.848405},  {"Городская больница г.Арзамас", -285.797210,581.851562,12.120290},   {"СМИ", -317.708038,821.221679,13.051450},  {"Воинская часть", 1703.197265,1678.025878,15.279437},  {"Арзамасская ОПГ", 438.705322,1046.505126,12.002637},  {"Батыревская ОПГ", 1941.203857,2161.006591,15.705187},  {"Лыткаринская ОПГ", -2346.002441,75.257041,21.002962},  {"Шахта", 2381.5727, 1726.4451, -2.1506},  {"Завод", -1062.6697, 2204.1894, 38.0964},  {"Инкосация", 1864.1374, 2011.7136, 15.8546},  {"Транспортная Компания", 2362.1115, 1972.5627, 15.5530},  {"База механиков", 1840.918090,-118.025146,15.695312},  {"Курьерская служба доставки", 2764.509765,-2396.882568,21.890625},  {"Аренда автобуса(Южный)", 2771.041992,-2454.780761,21.845964},  {"Аренда автобуса(Арзамас)", -127.487670,943.652648,12.142824},   {"Аренда автобуса(Батырево)", 1798.986328,2529.591552,15.664262},  {"Гоночная трасса", -1568.7784, 1611.8305, 36.3971},  {"Дом на горе", -789.5397, -456.7479, 741.1422},  {"СТО и тюнинг-ателье", 1856.1375, -122.3266, 15.6888},  {"Аренда транспорта пгт.Батырево", 1763.641723,2255.673339,15.865348},  {"Аренда транспорта г.Арзамас", -36.923530,1360.673583,12.002090},  {"Аренда транспорта г.Южный", 1966.599975,-2603.943603,10.820312},  {"Тайный интерьер в Лыткарино", -2424.5818, 2846.3291, 40.7908} };