Проблема с выбором скина

[22]

  Код (открыть спойлер)

player_info[playerid][AGE] = strval(inputtext);
            
            new regmaleskins[3][4] =
            {
                (19,21,22,28),//18-29
                   (24,25,36,67),//30-45
                   (14,142,102,103)//46-60
                   
            };
            new regfemaleskins[3][2] =
            {
                (13,69),//18-29
                (9,190),//30-45
                (10,218)//46-60
            };
            
               new newskinindex;
              switch(player_info[playerid][AGE])
            {
                case 18..29: {}
                case 30..45: newskinindex++;
                case 46..60: newskinindex+=2;
            }
            if(player_info[playerid][GENDER] == 1) player_info[playerid][SKIN] = regmaleskins[newskinindex][random(4)];
            else player_info[playerid][SKIN] = regfemaleskins[newskinindex][random(2)];
            printf("%d", player_info[playerid][SKIN]);

 

 

Должно выбирать скин под тот возраст который вписали в процессе регистрации, то есть если я выберу возраст от 18-ти до 29-ти, мне  должно подсунуть рандомный скин из этих (19,21,22,28), но оно мне выводит постоянно 0, я хз в чем проблема

[559]

@PEPITOSIK, сейчас обратил внимание на форму записей массивов. Откровенно говоря, впервые вижу, чтобы двумерный массив задавался круглыми скобками. Возможно, синтаксис Pawn действительно это позволяет, просто я не знал. А возможно и некоторый баг в первую очередь компилятора, который допускает такое. Попробуйте задать массивы следующим образом:

  Код (открыть спойлер)

new regmaleskins[3][4] =
{
	{19,21,22,28}, //18-29
	{24,25,36,67}, //30-45
	{14,142,102,103} //46-60
	
};
new regfemaleskins[3][2] =
{
	{13,69}, //18-29
	{9,190}, //30-45
	{10,218} //46-60
};

 

 

[1]

  В 4/26/2020 в 19:50, PEPITOSIK сказал:

  Код (открыть спойлер)

player_info[playerid][AGE] = strval(inputtext);
            
            new regmaleskins[3][4] =
            {
                (19,21,22,28),//18-29
                   (24,25,36,67),//30-45
                   (14,142,102,103)//46-60
                   
            };
            new regfemaleskins[3][2] =
            {
                (13,69),//18-29
                (9,190),//30-45
                (10,218)//46-60
            };
            
               new newskinindex;
              switch(player_info[playerid][AGE])
            {
                case 18..29: {}
                case 30..45: newskinindex++;
                case 46..60: newskinindex+=2;
            }
            if(player_info[playerid][GENDER] == 1) player_info[playerid][SKIN] = regmaleskins[newskinindex][random(4)];
            else player_info[playerid][SKIN] = regfemaleskins[newskinindex][random(2)];
            printf("%d", player_info[playerid][SKIN]);

Должно выбирать скин под тот возраст который вписали в процессе регистрации, то есть если я выберу возраст от 18-ти до 29-ти, мне  должно подсунуть рандомный скин из этих (19,21,22,28), но оно мне выводит постоянно 0, я хз в чем проблема

Читать далее...  

Возможно, проблема в регистрации. Может код для возвраста не работает?

[22]

  В 4/27/2020 в 18:49, Владимир Шкуматов сказал:

Возможно, проблема в регистрации. Может код для возвраста не работает?

Читать далее...  

В регистрации проблем вроде бы нет могу весть мод скинуть

Отредактировано 27 апреля, 2020 пользователем PEPITOSIK

[559]

@PEPITOSIK, ну, показывайте, где возраст записывается в переменную.

[22]

  В 4/28/2020 в 08:15, odosenok сказал:

@PEPITOSIK, ну, показывайте, где возраст записывается в переменную.

Читать далее...  

  Code (открыть спойлер)

#include <a_samp>
#include <fix>
#include <a_mysql>
#include <streamer>
#include <Pawn.Cmd>
#include <sscanf2>
#include <foreach>
#include <Pawn.Regex>
#include <crashdetect>

#define     MYSQL_HOST "localhost"
#define     MYSQL_USER "root"
#define     MYSQL_PASS ""
#define     MYSQL_BASE "sandbd"

#define     SCM     SendClientMessage
#define     SCMTA   SendClientMessageToAll
#define     SPD     ShowPlayerDialog

#define COLOR_WHITE 0xFFFFFFFF
#define COLOR_RED   0xCA3D35FF

main()
{
	print("\n----------------------------------");
	print(" Test mod enabled");
	print("----------------------------------\n");
}

//=================================== Переменные ===============================
//------------------------------------ Мусорка ---------------------------------
new MySQL:dbHandle;
//------------------------------------------------------------------------------
//==============================================================================

enum player
{
	ID,
	NAME[MAX_PLAYER_NAME],
	PASSWORD[65],
	SALT[11],
	EMAIL[64],
	REF,
	GENDER,
	FROM,
	AGE,
	SKIN,
}

new player_info[MAX_PLAYERS][player];

enum dialogs
{
	DLG_NONE,
	DLG_REG,
	DLG_REGEMAIL,
	DLG_REGREF,
	DLG_REGGENDER,
 	DLG_REGFROM,
 	DLG_REGAGE,
	DLG_LOG,
}

public OnGameModeInit()
{
	ConnectMySQL();
	return 1;
}

stock ConnectMySQL()
{
	dbHandle = mysql_connect(MYSQL_HOST, MYSQL_USER, MYSQL_PASS, MYSQL_BASE);
	switch(mysql_errno())
	{
		case 0: print("Подключение к MySQL успешно");
		default: print("Невозможно подключится к MySQL");
	}
	mysql_log(ERROR | WARNING);
	mysql_set_charset("cp1251");
}

public OnGameModeExit()
{
	return 1;
}

public OnPlayerRequestClass(playerid, classid)
{
	return 1;
}

public OnPlayerConnect(playerid)
{
	GetPlayerName(playerid, player_info[playerid][NAME], MAX_PLAYER_NAME);
	static const fnt_query[] = "SELECT `id` FROM `users` WHERE `name` = '%s'";
	new query[sizeof(fnt_query)+(-2+MAX_PLAYER_NAME)];
	format(query, sizeof(query), fnt_query, player_info[playerid][NAME]);
	mysql_tquery(dbHandle, query, "CheckRegistration", "i", playerid);
	return 1;
}

forward CheckRegistration(playerid);
public CheckRegistration(playerid)
{
	new rows;
	cache_get_row_count(rows);
	if(rows) ShowLogin(playerid);
	else ShowRegistration(playerid);
	
}

stock ShowLogin(playerid)
{
	SCM(playerid, COLOR_WHITE, "Игрок зарегистрирован");
}

stock ShowRegistration(playerid)
{
    new dialog[400+(-2+MAX_PLAYER_NAME)];
    format(dialog, sizeof(dialog),
		"{FFFFFF}Уважаемый {00F777}%s{FFFFFF}, мы рады видеть вас на {F7D044}Test RolePlay{FFFFFF}\n\
		Аккаунт с таким ником не зарегистрирован\n\
		Для игры на сервере вы должны пройти регистрацию\n\n\
		Придумайте пароль для вашего будущего аккаунта, и нажмите\"Далее\"\n\
		{F77D6F}\t* Пароль должен быть от 8-ми до 32-ух символов\n\
		\t* Пароль должен состоять только из цифр и латинских символов любого регистра",
	player_info[playerid][NAME]
	);
	SPD(playerid, DLG_REG, DIALOG_STYLE_INPUT, "{EDA612}1 {FFFFFF}| Ввод пароля", dialog, "Далее", "Выход");
}

public OnPlayerDisconnect(playerid, reason)
{
	return 1;
}

public OnPlayerSpawn(playerid)
{
	return 1;
}

public OnPlayerDeath(playerid, killerid, reason)
{
	return 1;
}

public OnVehicleSpawn(vehicleid)
{
	return 1;
}

public OnVehicleDeath(vehicleid, killerid)
{
	return 1;
}

public OnPlayerText(playerid, text[])
{
	return 1;
}

public OnPlayerCommandText(playerid, cmdtext[])
{
	if (strcmp("/mycommand", cmdtext, true, 10) == 0)
	{
		// Do something here
		return 1;
	}
	return 0;
}

public OnPlayerEnterVehicle(playerid, vehicleid, ispassenger)
{
	return 1;
}

public OnPlayerExitVehicle(playerid, vehicleid)
{
	return 1;
}

public OnPlayerStateChange(playerid, newstate, oldstate)
{
	return 1;
}

public OnPlayerEnterCheckpoint(playerid)
{
	return 1;
}

public OnPlayerLeaveCheckpoint(playerid)
{
	return 1;
}

public OnPlayerEnterRaceCheckpoint(playerid)
{
	return 1;
}

public OnPlayerLeaveRaceCheckpoint(playerid)
{
	return 1;
}

public OnRconCommand(cmd[])
{
	return 1;
}

public OnPlayerRequestSpawn(playerid)
{
	return 1;
}

public OnObjectMoved(objectid)
{
	return 1;
}

public OnPlayerObjectMoved(playerid, objectid)
{
	return 1;
}

public OnPlayerPickUpPickup(playerid, pickupid)
{
	return 1;
}

public OnVehicleMod(playerid, vehicleid, componentid)
{
	return 1;
}

public OnVehiclePaintjob(playerid, vehicleid, paintjobid)
{
	return 1;
}

public OnVehicleRespray(playerid, vehicleid, color1, color2)
{
	return 1;
}

public OnPlayerSelectedMenuRow(playerid, row)
{
	return 1;
}

public OnPlayerExitedMenu(playerid)
{
	return 1;
}

public OnPlayerInteriorChange(playerid, newinteriorid, oldinteriorid)
{
	return 1;
}

public OnPlayerKeyStateChange(playerid, newkeys, oldkeys)
{
	return 1;
}

public OnRconLoginAttempt(ip[], password[], success)
{
	return 1;
}

public OnPlayerUpdate(playerid)
{
	return 1;
}

public OnPlayerStreamIn(playerid, forplayerid)
{
	return 1;
}

public OnPlayerStreamOut(playerid, forplayerid)
{
	return 1;
}

public OnVehicleStreamIn(vehicleid, forplayerid)
{
	return 1;
}

public OnVehicleStreamOut(vehicleid, forplayerid)
{
	return 1;
}

public OnDialogResponse(playerid, dialogid, response, listitem, inputtext[])
{
	switch(dialogid)
	{
		case DLG_REG:
		{
			if(response)
			{
			    if(!strlen(inputtext))
			    {
			        ShowRegistration(playerid);
			        return SCM(playerid, COLOR_RED, "[Ошибка] {FFFFFF}Введите пароль в поле ниже и нажмите \"Далее\"");
				}
				if(strlen(inputtext) < 8 || strlen(inputtext) > 32)
				{
				    ShowRegistration(playerid);
			        return SCM(playerid, COLOR_RED, "[Ошибка] {FFFFFF}Длина пароля должна быть от 8-ми до 32-ух символов");
				}
				new regex:rg_passwordcheck = regex_new("^[a-zA-Z0-9]{1,}$");
				if(regex_check(inputtext, rg_passwordcheck))
				{
				    new salt[11];
				    for(new i; i < 10; i++)
				    {
						salt[i] = random(79) + 47;
					}
					salt[10] = 0;
					SHA256_PassHash(inputtext, salt, player_info[playerid][PASSWORD], 64);
					strmid(player_info[playerid][SALT], salt, 0, 11, 11);
					printf("%s", player_info[playerid][SALT]);
					//strmid(player_info[playerid][PASSWORD], inputtext, 0, strlen(inputtext), 32);
					SPD(playerid, DLG_REGEMAIL, DIALOG_STYLE_INPUT, "{EDA612}2 {FFFFFF}| Ввод Email адреса",
						"{FFFFFF}Введите ваш настояший Email адрес\n\
						Если вы потеряете доступ к аккаунту, то вы сможете его востановить через Email\n\
						Введите его в поле ниже и нажмите \"Далее\"",
					"Далее", "");
				}
				else
				{
                    ShowRegistration(playerid);
			        return SCM(playerid, COLOR_RED, "[Ошибка] {FFFFFF}Пароль может состоять только из чисел и латинских символов любого регистра");
				}
				regex_delete(rg_passwordcheck);
			}
			else
			{
			    SCM(playerid, COLOR_RED, "Используйте \"/q\" чтобы выйти");
			    SPD(playerid, -1, 0, " ", " ", " ", "");
			    return Kick(playerid);
			}
		}
		case DLG_REGEMAIL:
		{
            if(!strlen(inputtext))
            {
	            SPD(playerid, DLG_REGEMAIL, DIALOG_STYLE_INPUT, "{EDA612}2 {FFFFFF}| Ввод Email адреса",
					"{FFFFFF}Введите ваш настояший Email адрес\n\
					Если вы потеряете доступ к аккаунту, то вы сможете его востановить через Email\n\
					Введите его в поле ниже и нажмите \"Далее\"",
				"Далее", "");
				return SCM(playerid, COLOR_RED, "[Ошибка] {FFFFFF}Введите свой Email в поле ниже и нажмите \"Далее\"");
			}
			new regex:rg_emailcheck = regex_new("^[a-zA-Z0-9._-]{1,43}@[a-zA-Z]{1,12}.[a-zA-Z]{1,8}$");
			if(regex_check(inputtext, rg_emailcheck))
			{
				strmid(player_info[playerid][EMAIL], inputtext, 0, strlen(inputtext), 64);
			    SPD(playerid, DLG_REGREF, DIALOG_STYLE_INPUT, "{EDA612}3 {FFFFFF}| Ввод пригласившего",
				"{FFFFFF}Если ты пришел по приглашени, то\n\
				можешь указать ник пригласившего в поле ниже:",
				"Далее", "Пропустить");
			}
			else
			{
                SPD(playerid, DLG_REGEMAIL, DIALOG_STYLE_INPUT, "{EDA612}2 {FFFFFF}| Ввод Email адреса",
					"{FFFFFF}Введите ваш настояший Email адрес\n\
					Если вы потеряете доступ к аккаунту, то вы сможете его востановить через Email\n\
					Введите его в поле ниже и нажмите \"Далее\"",
				"Далее", "");
			    return SCM(playerid, COLOR_RED, "[Ошибка] {FFFFFF}Укажите правильно ваш Email адрес");
			}
			regex_delete(rg_emailcheck);
		}
		case DLG_REGREF:
		{
			if(response)
			{
			    new regex:rg_refheck = regex_new("^[a-zA-Z_]{4,24}$");
				if(regex_check(inputtext, rg_refheck))
				{
				    static const fnt_query[] = "SELECT * FROM `users` WHERE `name` = '%s'";
					new query[sizeof(fnt_query)+(-2+MAX_PLAYER_NAME)];
					format(query, sizeof(query), fnt_query, inputtext);
					mysql_tquery(dbHandle, query, "CheckReferal", "is", playerid, inputtext);
				}
				else
				{
                    SPD(playerid, DLG_REGREF, DIALOG_STYLE_INPUT, "{EDA612}3 {FFFFFF}| Ввод пригласившего",
						"{FFFFFF}Если ты пришел по приглашени, то\n\
						можешь указать ник пригласившего в поле ниже:",
					"Далее", "Пропустить");
			        return SCM(playerid, COLOR_RED, "[Ошибка] {FFFFFF}Введите ник пригласившего");
				}
				regex_delete(rg_refheck);
			}
			else
			{
			    SPD(playerid, DLG_REGGENDER, DIALOG_STYLE_MSGBOX, "{EDA612}4 {FFFFFF}| Выбор пола персонажа",
					"{FFFFFF}Виберите пол вашего персонажа:",
				"Мужской", "Женский");
			}
		}
		case DLG_REGGENDER:
		{
		    if(response) player_info[playerid][GENDER] = 1;
			else player_info[playerid][GENDER] = 2;
			SPD(playerid, DLG_REGFROM, DIALOG_STYLE_LIST, "{EDA612}5 {FFFFFF}| Выбор места проживания",
				"Los Santos\n\
				Las Venturas\n\
				San Fierro",
			"Далее", "");
		}
		case DLG_REGFROM:
		{
	  		switch(listitem)
	  		{
	  		    case 0: player_info[playerid][FROM] = 1;
	  		    case 1: player_info[playerid][FROM] = 2;
	  		    case 2: player_info[playerid][FROM] = 3;
			}
			SPD(playerid, DLG_REGAGE, DIALOG_STYLE_INPUT, "{EDA612}6 {FFFFFF}| Ввод возраста",
				"{FFFFFF}Введите возраст вашего будущего персонажа:\n\
				{F77D6F}\t* Введите возраст от 18-ти до 60-ти",
			"Далее", "");
		}
		case DLG_REGAGE:
		{
		    if(!strlen(inputtext))
		    {
	      		SPD(playerid, DLG_REGAGE, DIALOG_STYLE_INPUT, "{EDA612}6 {FFFFFF}| Ввод возраста",
					"{FFFFFF}Введите возраст вашего будущего персонажа:\n\
					{F77D6F}\t* Введите возраст от 18-ти до 60-ти",
				"Далее", "");
				return SCM(playerid, COLOR_RED, "[Ошибка] {FFFFFF}Введите свой возраст в поле ниже и нажмите \"Далее\"");
			}
			if(strval(inputtext) < 18 || strval(inputtext) > 60)
			{
	   			SPD(playerid, DLG_REGAGE, DIALOG_STYLE_INPUT, "{EDA612}2 {FFFFFF}| Ввод возраста",
					"{FFFFFF}Введите возраст вашего будущего персонажа:\n\
					{F77D6F}\t* Введите возраст от 18-ти до 60-ти",
				"Далее", "");
				return SCM(playerid, COLOR_RED, "[Ошибка] {FFFFFF}Введите свой возраст от 18-ти до 60-ти");
			}
			player_info[playerid][AGE] = strval(inputtext);
			
			new regmaleskins[3][4] =
			{
			    (19,21,22,28),//18-29
	   			(24,25,36,67),//30-45
	   			(14,142,102,103)//46-60
	   			
			};
			new regfemaleskins[3][2] =
			{
				(13,69),//18-29
				(9,190),//30-45
				(10,218)//46-60
			};
			
   			new newskinindex;
  			switch(player_info[playerid][AGE])
		    {
				case 18..29: {}
				case 30..45: newskinindex++;
				case 46..60: newskinindex+=2;
			}
			if(player_info[playerid][GENDER] == 1) player_info[playerid][SKIN] = regmaleskins[newskinindex][random(4)];
			else player_info[playerid][SKIN] = regfemaleskins[newskinindex][random(2)];
			printf("%d", player_info[playerid][SKIN]);
			SCM(playerid, COLOR_WHITE, "Регистрация завершена");
		}
	}
	return 1;
}

forward CheckReferal(playerid, referal[]);
public CheckReferal(playerid, referal[])
{
    new rows;
	cache_get_row_count(rows);
	if(rows)
	{
		new refid;
		cache_get_value_name_int(0, "id", refid);
		player_info[playerid][REF] = refid;
		SPD(playerid, DLG_REGGENDER, DIALOG_STYLE_MSGBOX, "{EDA612}4 {FFFFFF}| Выбор пола персонажа",
			"{FFFFFF}Виберите пол вашего персонажа:",
		"Мужской", "Женский");
	}
	else
	{
	    SPD(playerid, DLG_REGREF, DIALOG_STYLE_INPUT, "{EDA612}3 {FFFFFF}| Ввод пригласившего",
			"{FFFFFF}Если ты пришел по приглашени, то\n\
			можешь указать ник пригласившего в поле ниже:",
		"Далее", "Пропустить");
	    return SCM(playerid, COLOR_RED, "[Ошибка] {FFFFFF}Аккаунта с таким ником не существует");
	}
	return 1;
}

public OnPlayerClickPlayer(playerid, clickedplayerid, source)
{
	return 1;
}

 

Вот весь мод

Отредактировано 28 апреля, 2020 пользователем DEST

[559]

@PEPITOSIK, а выведите-ка AGE в консоль.

[22]

  В 4/28/2020 в 21:43, odosenok сказал:

@PEPITOSIK, а выведите-ка AGE в консоль.

Читать далее...  

вывел, и понял что проблема с AGE пойду исправлять, спасибо что откликнулись

 

  В 4/28/2020 в 21:43, odosenok сказал:

@PEPITOSIK, а выведите-ка AGE в консоль.

Читать далее...  

хотя все нормально в консоль вывелось

[22]

  В 5/1/2020 в 19:32, odosenok сказал:

@PEPITOSIK, сейчас обратил внимание на форму записей массивов. Откровенно говоря, впервые вижу, чтобы двумерный массив задавался круглыми скобками. Возможно, синтаксис Pawn действительно это позволяет, просто я не знал. А возможно и некоторый баг в первую очередь компилятора, который допускает такое. Попробуйте задать массивы следующим образом:

  Код (открыть спойлер)

new regmaleskins[3][4] =
{
	{19,21,22,28}, //18-29
	{24,25,36,67}, //30-45
	{14,142,102,103} //46-60
	
};
new regfemaleskins[3][2] =
{
	{13,69}, //18-29
	{9,190}, //30-45
	{10,218} //46-60
};

 

 

Читать далее...  

Огромное спасибо.