Помогите сделать команду /iban

Пожалуйста помогите сделать команду вечного бана(/iban).
Навсякий случай прикреплю обычный /ban(на время)

 

CMD:ban(playerid, params[])
{
//	if(a_info[playerid][aRankID]<10) return SendErrorMessage(playerid, m__no_admin);
	if(a_info[playerid][a_CMD][a_ban] < 1) return SendInf(playerid, "Командa {FFFF00}/ban Вам не доступна");

	new day, reason[31];
	if(isnull(params)) return SendInf(playerid, "Используйте: /ban [id] [дни] [причина]");
	sscanf(params, "uds[30]", paramss, day, reason);
	if(paramss == INVALID_PLAYER_ID) return SendErrorMessage(playerid, m__not_connected);
	if(!(1 <= day <= 30)) return SendErrorMessage(playerid, "Ошибка. Неверное количество дней.");
	if(a_info[paramss][aRankID] >= a_info[playerid][aRankID]) return SendErrorMessage(playerid, "Администратора выше/своего лвла нельзя забанить");
	if(a_info[playerid][aRankID] < 8 && p_info[paramss][tLeader]) return SendErrorMessage(playerid, "Лидера нельзя забанить");
	Reason__[playerid][0] = 0;

    if(ANTI_SPLIT_SERVER(playerid, reason, 5) == 0) return 1;
    string_replace(reason, "'", ' ');
	if(isnull(reason)) return SendInf(playerid, "Используйте: /ban [id] [дни] [причина]");
	else
	{
		format(stringer, MAX_CHAT_TEXT, "Администратор %s забанил игрока %s на %d дней. Причина: %s",NamePlayer[playerid],NamePlayer[paramss], day,reason);
		strcat(Reason__[playerid], reason);
	}
	if(GetString(NAME_SERVER_DEMO,"Divertal")) SendClientMessageToAll(0x003300FF, stringer);
	else SendClientMessageToAll(COLOR_LIGHTRED, stringer);
	WriteLog(TYPE_LOG_BAN,stringer);

	if(!GetPVarInt(paramss, "Full_Access"))
	{
		new unbandate = unix + day*86400;
		mysql_query_string[0] = EOS;
		format(mysql_query_string, MAX_SQL_BIG, "INSERT INTO `table_ban` (`Name_Admin`, `Name_Player`, `Ban_Data`, `Unban_Data`, `Ban_Reason`) VALUES ('%s', '%s', '%02d.%02d.%04d', '%d', '%s')", NamePlayer[playerid], NamePlayer[paramss],  tmpyear, tmpmonth, tmpday, unbandate, reason);
		mysql_pquery(connects, mysql_query_string, "", "");

		new ipreg[17];
		GetPVarString(paramss, "IpReg", ipreg, 16);

		format(stringer, MAX_CHAT_TEXT, "Nik 	[%s]	R-IP [%s]	L-IP  [%s] 	IP 	[%s]",NamePlayer[paramss],ipreg,PlayerIp[paramss],PlayerIp[paramss]);
		AdmMes(COLOR_LIGHTRED, stringer, 1);
		gAdmin[playerid][ADMIN_BAN] += 1;

		format(stringer, 512,
			"\
				{FFFFFF}Внимание! Вас только что {AA3333}забанили.\n\
				{FFFFFF}Вас забанил(а): {AA3333}%s\n\
				{FFFFFF}Время: {AA3333}%02d:%02d:%02d\n\
				{FFFFFF}Дата: {AA3333}%d.%d.%d\n\
				{FFFFFF}Причина: {AA3333}%s\n\
				{FFFFFF}Разбан через: {AA3333}%d дней\n\n\
				{FFFFFF}Если вы считаете это ошибкой и т. д. сделайте {AA3333}скриншот «F8» {FFFFFF}и отправьте на форум\
				Форум поддержки: {AA3333}"FORUM_URL"/\n{FFFFFF}Форум > Жалобы > {AA3333}Жалобы на администрацию\
			", NamePlayer[playerid], tmphour, tmpminute, tmpsecond, tmpyear, tmpmonth, tmpday, reason, day);
		ShowPlayerDialog(paramss,0000,DIALOG_STYLE_MSGBOX,"{AA3333}Информация",stringer,"Закрыть","");
		KickEx(paramss);
	}
	return 1;
}

 

[45]

@OGOGOGO, замени функцию этой:

Спойлер

forward Check_Ban_List(playerid,Name_Player[],Number_Ban);
public Check_Ban_List(playerid,Name_Player[],Number_Ban)
{
	new
		ADMIN_ISSUING_BAN[24],
		NAME_PLAYER[24],
		BAN_DATA[32],
		UNBAN_DATA,
		REASON_FOR_THE_BAN[50],
		rows;
		
	cache_get_row_count(rows);
	if(rows)
	{
		cache_get_value(0, "Name_Admin",ADMIN_ISSUING_BAN,24);
		cache_get_value(0, "Name_Player",NAME_PLAYER,24);
		cache_get_value(0, "Ban_Data",BAN_DATA,32);
		cache_get_value(0, "Ban_Reason",REASON_FOR_THE_BAN,50);
		cache_get_value_int(0, "Unban_Data",UNBAN_DATA);
		
		if(UNBAN_DATA == 0)
		{
			format(stringer,144,"Аккаунт: {"#cWHITE"}%s",Name_Player);
			SendClientMessage(playerid,0xFF6347FF,stringer);
			format(stringer,144,"Дата блокировки: {"#cWHITE"}%s",BAN_DATA);
			SendClientMessage(playerid,0xFF6347FF,stringer);
			format(stringer,144,"Администратор: {"#cWHITE"}%s",ADMIN_ISSUING_BAN);
			SendClientMessage(playerid,0xFF6347FF,stringer);
			format(stringer,144,"Причина: {"#cWHITE"}%s",REASON_FOR_THE_BAN);
			SendClientMessage(playerid,0xFF6347FF,stringer);
			SendClientMessage(playerid, 0xFF6347FF, "Дата разблокировки: {"#cWHITE"}никогда");
			return KickEx(playerid);
		}
		else if(UNBAN_DATA > unix)
		{
			format(stringer,144,"Аккаунт: {"#cWHITE"}%s",Name_Player);
			SendClientMessage(playerid,0xFF6347FF,stringer);
			format(stringer,144,"Дата блокировки: {"#cWHITE"}%s",BAN_DATA);
			SendClientMessage(playerid,0xFF6347FF,stringer);
			format(stringer,144,"Администратор: {"#cWHITE"}%s",ADMIN_ISSUING_BAN);
			SendClientMessage(playerid,0xFF6347FF,stringer);
			format(stringer,144,"Причина: {"#cWHITE"}%s",REASON_FOR_THE_BAN);
			SendClientMessage(playerid,0xFF6347FF,stringer);
			new days, date_ban[6];
			//TimestampToDate(UNBAN_DATA,date_ban[0],date_ban[1],date_ban[2],date_ban[3],date_ban[4],date_ban[5],2);
            gmtime(UNBAN_DATA + 2 * 60,date_ban[0],date_ban[1],date_ban[2],date_ban[3],date_ban[4],date_ban[5]);
			format(stringer, 144, "Дата разблокировки: {"#cWHITE"}%02d/%02d/%02d %02d:%02d:%02d (%d дней)",date_ban[2],date_ban[1],date_ban[0],date_ban[3],date_ban[4],date_ban[5],days);
			SendClientMessage(playerid,0xFF6347FF,stringer);
			if(Number_Ban == 2) return KickEx(playerid);
		}
		else
		{
			mysql_query_string[0] = EOS;
			format(mysql_query_string, 200, "DELETE FROM `table_ban` WHERE `Name_Player` = '%s'",Name_Player);
			mysql_pquery(connects, mysql_query_string, "","");
			SetPVarInt(playerid,"table_ban",1);
			return 1;
		}
	}
	else
	{
		if(Number_Ban == 1) return SendErrorMessage(playerid, "Игрок не был заблокирован");
		SetPVarInt(playerid,"table_ban",1);
	}
	return 1;
}

 

 

И добавь такую команду:

Спойлер

CMD:iban(playerid, params[])
{
	if(a_info[playerid][a_CMD][a_ban] < 1) return SendInf(playerid, "Командa {FFFF00}/iban Вам не доступна");

	new reason[31];
	if(isnull(params)) return SendInf(playerid, "Используйте: /iban [id] [причина]");
	sscanf(params, "us[30]", paramss, reason);
	if(paramss == INVALID_PLAYER_ID) return SendErrorMessage(playerid, m__not_connected);
	if(a_info[paramss][aRankID] >= a_info[playerid][aRankID]) return SendErrorMessage(playerid, "Администратора выше/своего лвла нельзя забанить");
	if(a_info[playerid][aRankID] < 8 && p_info[paramss][tLeader]) return SendErrorMessage(playerid, "Лидера нельзя забанить");
	Reason__[playerid][0] = 0;

    if(ANTI_SPLIT_SERVER(playerid, reason, 5) == 0) return 1;
    string_replace(reason, "'", ' ');
	if(isnull(reason)) return SendInf(playerid, "Используйте: /iban [id] [дни] [причина]");
	else
	{
		format(stringer, MAX_CHAT_TEXT, "Администратор %s забанил игрока %s навсегда. Причина: %s",NamePlayer[playerid],NamePlayer[paramss], reason);
		strcat(Reason__[playerid], reason);
	}
	if(GetString(NAME_SERVER_DEMO,"Divertal")) SendClientMessageToAll(0x003300FF, stringer);
	else SendClientMessageToAll(COLOR_LIGHTRED, stringer);
	WriteLog(TYPE_LOG_BAN,stringer);

	if(!GetPVarInt(paramss, "Full_Access"))
	{
		mysql_query_string[0] = EOS;
		format(mysql_query_string, MAX_SQL_BIG, "INSERT INTO `table_ban` (`Name_Admin`, `Name_Player`, `Ban_Data`, `Unban_Data`, `Ban_Reason`) VALUES ('%s', '%s', '%02d.%02d.%04d', '%d', '%s')", NamePlayer[playerid], NamePlayer[paramss],  tmpyear, tmpmonth, tmpday, 0, reason);
		mysql_pquery(connects, mysql_query_string, "", "");

		new ipreg[17];
		GetPVarString(paramss, "IpReg", ipreg, 16);

		format(stringer, MAX_CHAT_TEXT, "Nik 	[%s]	R-IP [%s]	L-IP  [%s] 	IP 	[%s]",NamePlayer[paramss],ipreg,PlayerIp[paramss],PlayerIp[paramss]);
		AdmMes(COLOR_LIGHTRED, stringer, 1);
		gAdmin[playerid][ADMIN_BAN] += 1;

		format(stringer, 512,
			"\
				{FFFFFF}Внимание! Вас только что {AA3333}забанили.\n\
				{FFFFFF}Вас забанил(а): {AA3333}%s\n\
				{FFFFFF}Время: {AA3333}%02d:%02d:%02d\n\
				{FFFFFF}Дата: {AA3333}%d.%d.%d\n\
				{FFFFFF}Причина: {AA3333}%s\n\
				{FFFFFF}Дата разбана: {AA3333}никогда\n\n\
				{FFFFFF}Если вы считаете это ошибкой и т. д. сделайте {AA3333}скриншот «F8» {FFFFFF}и отправьте на форум\
				Форум поддержки: {AA3333}"FORUM_URL"/\n{FFFFFF}Форум > Жалобы > {AA3333}Жалобы на администрацию\
			", NamePlayer[playerid], tmphour, tmpminute, tmpsecond, tmpyear, tmpmonth, tmpday, reason);
		ShowPlayerDialog(paramss,0000,DIALOG_STYLE_MSGBOX,"{AA3333}Информация",stringer,"Закрыть","");
		KickEx(paramss);
	}
	return 1;
}

 

 

[45]

@OGOGOGO, покажи код, где стоит проверка, не забанен ли игрок.

forward Check_Ban_List(playerid,Name_Player[],Number_Ban);
public Check_Ban_List(playerid,Name_Player[],Number_Ban)
{
	new ADMIN_ISSUING_BAN[24], NAME_PLAYER[24], BAN_DATA[32], UNBAN_DATA, REASON_FOR_THE_BAN[50];
	new rows;
	cache_get_row_count(rows);
	if(rows)
	{
		cache_get_value(0, "Name_Admin",ADMIN_ISSUING_BAN,24);
		cache_get_value(0, "Name_Player",NAME_PLAYER,24);
		cache_get_value(0, "Ban_Data",BAN_DATA,32);
		cache_get_value(0, "Ban_Reason",REASON_FOR_THE_BAN,50);
		cache_get_value_int(0, "Unban_Data",UNBAN_DATA);
		if(UNBAN_DATA > unix)
		{
			format(stringer,144,"Аккаунт: {"#cWHITE"}%s",Name_Player);
			SendClientMessage(playerid,0xFF6347FF,stringer);
			format(stringer,144,"Дата блокировки: {"#cWHITE"}%s",BAN_DATA);
			SendClientMessage(playerid,0xFF6347FF,stringer);
			format(stringer,144,"Администратор: {"#cWHITE"}%s",ADMIN_ISSUING_BAN);
			SendClientMessage(playerid,0xFF6347FF,stringer);
			format(stringer,144,"Причина: {"#cWHITE"}%s",REASON_FOR_THE_BAN);
			SendClientMessage(playerid,0xFF6347FF,stringer);
			new days, date_ban[6];
			//TimestampToDate(UNBAN_DATA,date_ban[0],date_ban[1],date_ban[2],date_ban[3],date_ban[4],date_ban[5],2);
            gmtime(UNBAN_DATA + 2 * 60,date_ban[0],date_ban[1],date_ban[2],date_ban[3],date_ban[4],date_ban[5]);
			format(stringer, 144, "Дата разблокировки: {"#cWHITE"}%02d/%02d/%02d %02d:%02d:%02d (%d дней)",date_ban[2],date_ban[1],date_ban[0],date_ban[3],date_ban[4],date_ban[5],days);
			SendClientMessage(playerid,0xFF6347FF,stringer);
			if(Number_Ban == 2) return KickEx(playerid);
		}
		else
		{
			mysql_query_string[0] = EOS;
			format(mysql_query_string, 200, "DELETE FROM `table_ban` WHERE `Name_Player` = '%s'",Name_Player);
			mysql_pquery(connects, mysql_query_string, "","");
			SetPVarInt(playerid,"table_ban",1);
			return 1;
		}
	}
	else
	{
		if(Number_Ban == 1) return SendErrorMessage(playerid, "Игрок не был заблокирован");
		SetPVarInt(playerid,"table_ban",1);
	}
	return 1;
}

 

18 минут назад, Talex сказал:

@OGOGOGO, покажи код, где стоит проверка, не забанен ли игрок.

 Вот вроде

@Talex
Огромное человеческое спасибо!