Question

Спойлер

#define vehicle_type_server     1
#define vehicle_type_player     2
#define vehicle_type_job        3
#define vehicle_type_admin      4

enum vehicle
{
    id,
    type,
    model,
    vehicle_id,
    owner,
    color[2],
    Float:position[4],
    Float:fuel,
    Float:milage,
    Float:health,
    bool:locked
   
}

new veh_info[MAX_VEHICLES][vehicle];

CMD:lock(playerid)
{
    if(IsValidVehicle(GetPlayerVehicleID(playerid)))
    {
        new vehicleid = GetPlayerVehicleID(playerid);
        if(veh_info[vehicleid - 1][type] != vehicle_type_player || veh_info[vehicleid - 1][owner] != PlayerInfo[playerid][id]) return SendClientMessage(playerid, color_gray,"Нет ключей от транспорта.");
        PlayerPlaySound(playerid, 11450.00.00.0);
        //сток блокировки дверей
        return 1;
    }
    else
    {
        new Float:x,
            Float:y,
            Float:z;
           
        GetVehiclePos(); // тут вроде должны получить коорды авто
        IsPlayerInRangeOfPoint() // чекнуть находится ли игрок в радиусе с авто
    }
    return 1;
}

callback: users_vehicles_loading()
{
    new rows, fields;
   
    cache_get_data(rows, fields);
   
    if(rows)
    {
        for(new i = 0; i < rows; i++)
        {
            veh_info[i][type] = vehicle_type_player;
           
            veh_info[i][id] = cache_get_field_content_int(i, "v_id", sql_connection);
            veh_info[i][model] = cache_get_field_content_int(i, "v_model", sql_connection);
            veh_info[i][owner] = cache_get_field_content_int(i, "v_owner", sql_connection);
            veh_info[i][color][0] = cache_get_field_content_int(i, "v_color_1", sql_connection);
            veh_info[i][color][1] = cache_get_field_content_int(i, "v_color_2", sql_connection);
           
            veh_info[i][fuel] = cache_get_field_content_int(i, "v_fuel", sql_connection);
            veh_info[i][milage] = cache_get_field_content_int(i, "v_milage", sql_connection);
           
            veh_info[i][position][0] = cache_get_field_content_int(i, "v_pos_x", sql_connection);
            veh_info[i][position][1] = cache_get_field_content_int(i, "v_pos_y", sql_connection);
            veh_info[i][position][2] = cache_get_field_content_int(i, "v_pos_z", sql_connection);
            veh_info[i][position][3] = cache_get_field_content_int(i, "v_pos_a", sql_connection);
           
            veh_info[i][vehicle_id] = CreateVehicle(veh_info[i][model], veh_info[i][position][0], veh_info[i][position][1], veh_info[i][position][2], veh_info[i][position][3], veh_info[i][color][0], veh_info[i][color][1], 5001);
        }
    }
   
    printf("Автомобилей игроков загружено: %d", rows);
    return 1;
}

 

Не много не понимаю как реализовать открытие/закрытие авто с определенного радиуса. Помогите пожалуйста). Хранение автомобилей сделал в базе данных. Расскажите пожалуйста это хорошо (в плане оптимизации/будущих апдейтов, т.к. планирую хранить не только игровой транспорт, но и аренды,фракций и т.д.)?

Edited by NO2037

Share this post


Link to post

2 answers to this question

  • 0

@NO2037, немного нехорошо в плане дальнейшего ведения проекта (зачем использовать иностранные слова там, где суть можно передать русскими? Это я про апдейты) – использовать макросы (директивы #define) там, где можно и даже нужно использовать перечисления (enum).

enum {
    VEHICLE_TYPE_SERVER = 1,
    VEHICLE_TYPE_PLAYER, // и не нужно указывать номер: нумерация идет автоматически
    VEHICLE_TYPE_JOB,
    VEHICLE_TYPE_ADMIN
};

 

Если же вопрос заключался в самой идее хранения всевозможных типов транспорта (правда слово тип меня здесь смущает) в базе данных, так я и сам приверженец того, что вы реализованы. Вообще все, что можно хранить отдельно, имеет смысл хранить отдельно. На некоторых игровых проектах, например, весь маппинг хранится тоже в базе данных. Это позволяет разработчикам игровых карт редактировать их так, как они считают нужным, и вносить изменения на сервер, не прикасаясь к игровому моду и базе данных, вручную, а также не отвлекая от своих дел разработчиков игрового мода.

 

Касаемо вопроса реализации.

Спойлер

CMD:lock(playerid) {

    static const Float:LOCK_MAX_DISTANCE = 20.0// радиус действия команды от автомобиля

    new vehicleid = GetPlayerVehicleID(playerid); // если vehicleid = 0, значит игрок не в т/с; иначе – внутри т/с
    if (vehicleid == 0) { // игрок не в автомобиле => дистанционное открытие/закрытие
        for (new i = 0; i < MAX_VEHICLES; i++) { // ищем все т/с рядом с игроком
            if (!IsValidVehicle(veh_info[i][vehicle_id])) { // если транспорта не существует
                continue// уходим на следующую итерацию
            }

            new Float:x, Float:y, Float:z; // лучше вне цикла, но, думаю, компилятор оптимизирует объявление переменных сам
            GetVehclePos(i, x, y, z);

            if (GetPlayerDistanceFromPoint(playerid, x, y, z) > LOCK_MAX_DISTANCE) { // слишком далеко находится транспортное средство
                continue// уходим на следующую итерацию
            }

            // сюда добавьте проверку, может ли игрок открывать этот автомобиль
            // если не может, ищите дальше. Возможно, рядом стоит много автомобилей
            // и среди них есть тот, который игрок сможет открыть

            // как только убедились, что рядом есть транспортное средство и мы можем его открыть
            // сохраняем ID этого транспортного средства и выходим из цикла
            vehicleid = i;
            break;
        }

        if (vehicleid == 0) { // если так и не нашли ни одно т/с рядом с игроком, которое он может открыть
            return SendClientMessage(playerid, -1"Рядом нет т/с, которые вы можете открыть/закрыть") & 0;
        }
    }

    // теперь в vehicleid записан ID т/с, которое мы можем открыть/закрыть. Осталось лишь сделать это
    PlayerPlaySound(playerid, 11450.00.00.0);
    // вызов функции открытия/блокировки дверей

    return true;
}

 

 

---

И давайте все же называть вещи своими именами. Есть переменные, есть функции, есть маркеры (они же ключевые слова). Выражение "сток блокировки дверей" – это все, что сказать "статик блокировки дверей". И нельзя говорить, что ключевые слова stock или public относятся к функциям – с таким же успехом могут быть объявлены и переменные с маркерами stock и public.

 

Спойлер


/*
    глобальная переменная
    область видимости ограничена одним файлом
    (доступ к переменной возможен только из этого файла)
*/

static var = 0;
static const var = 0// аналогично, но нельзя изменить значение

static stock var = 0// если переменная не используется, компилятор ее выбросит
static const stock var = 0// аналогично

/*
    глобальная переменная
    доступ к переменной возможен из любой точки ниже объявления данной переменной
    в примерах ниже показано, что new можно опускать
*/

new var = 0;
new stock var = 0// если переменная не используется, компилятор ее выбросит
stock var = 0// то же самое

new const var = 0// аналогично, но нельзя изменить значение
const var = 0// то же самое
const stock var = 0// то же самое

/*
    глобальная публичная переменная
    обратиться к переменной можно из фильтрскриптов
*/

new public var = 0;
new public stock var = 0// если переменная не используется, компилятор ее выбросит
new public const var = 0// переменную нельзя изменить
new public const stock var = 0;

public var = 0// ключевое слово new можно упускать
public const var = 0;
public const stock var = 0;

/*
    статические функции
*/

static someFunc() {
    // доступ к функции возможен только из этого файла
}

static stock someFunc() {
    // доступ к функции возможен только из этого файла
    // если функция не используется, компилятор ее выбросит
}

/*
    глобальные функции
*/

someFunc() {
    // и не нужен никакой stock
    // это самая обычная функция
}

stock someFunc() {
    // а это обычная функция
    // но если она не используется, компилятор ее выкинет
}

/*
    глобальные публичные функции
*/

forward someFunc();
public someFunc() {
    // доступ к функции возможен из фильтрскриптов
}

@someFunc();
@someFunc() {
    // это то же самое, что и forward + public
    // главное, чтобы первый символ был @
    // тогда ключевые слова forward и public писать не нужно
}

 

 

 

Share this post


Link to post
  • 0

@Cawfee Ну я так описал вкратце.. смысл я думаю был понятен). Ошибки понял, исправим. Благодарю за столь обширный и информативный ответ.

Edited by NO2037

Share this post


Link to post
Guest
This topic is now closed to further replies.
Sign in to follow this  
Followers 0
  • Recently Browsing   0 members

    No registered users viewing this page.

  • Similar Content

    • kekkomomek1941
      By kekkomomek1941
      Всем привет. Мне надоело перекомпилировать мод каждый раз, поэтому я хочу сделать, чтобы через например settings.ini настраивались сайт моего сервера, вк моего сервера и т.п , только я не знаю, как это сделать
      Буду благодарен, если поможете