[закрыто] Ограничение баг-репортов на одного игрока

[trevison Хороший 14]

Некорректно срабатывает функция проверки на кол-во баг-репортов. У игрока меньше 5 баг-репортов и ему выдаёт ошибку.

#define MAX_BUGS_PLAYER 5 // Макс. к-во багов для 1 игрока

// проверка при попытке отправить баг-репорт
if(getPlayerBugs(playerid) >= MAX_BUGS_PLAYER) return SendErr(playerid, "У вас максимальное кол-во отправленных баг-репортов!");

// функция
stock getPlayerBugs(playerid)
{
    new pBugs = 0;
    for(new i = 0; i < MAX_BUGS; i++) {if(strcmp(pData[playerid][pNickname],gBugDataName[i][0])) ++pBugs;}
    return pBugs;
}

 

Edited July 29 by trevison

[Cawfee Максимальный 529]

@trevison, а, так вы выгружаете из базы данных всю имеющуюся там информацию о багах, но ее меньше, чем размер вашего массива. В итоге получается, что gBugDataName[index], где index = числов_репортов и выше, хранит пустую строку. Функция strcmp, если одна из строк пустая, возвращает 0 (якобы строки совпадают). Потому и говорят всегда инициализировать все, что только можно, чтобы в будущем не словить никаких казусов. Тем не менее, хорошо, что все решилось.

[Sleash Очень хороший 127]

Благодаря этой строке

cache_get_field_content(i, "name", gBugDataName[id], 1, 25);

видно, что массив выглядит примерно так:

gBugDataName[id] = {
    "Nick_Name",
    "Oleg_Sleash",
    "Roger_Evans",
    "Calcor_Samp"
};

То есть, когда вы используете gBugDataName[0], то вы получаете "Nick_Name" (именно строку с ником), а если gBugDataName[0][0], то только 0-й символ первого ника, а именно 'N', теперь и думайте, как правильно делать проверки на ник.

[Cawfee Максимальный 529]

1 минуту назад, trevison сказал:

gBugDataName[i][0]

Снова только первую ячейку имени берете?

[trevison Хороший 14]

как понимать первую ячейку?

в прошлый раз я проверку на соответствие ников вот так написал:

if(strcmp(gBugDataName[0], pData[playerid][pNickname])) continue;

и всё работает как и задумано

сейчас же я точно такую же проверку делаю

[Cawfee Максимальный 529]

@trevison, как объявлена переменная gBugDataName?

[trevison Хороший 14]

new gBugDataName[MAX_BUGS][25];

[Sleash Очень хороший 127]

Так правильно, strcmp сравнивает первый символ gBugDataName и ник игрока, они не сходятся, но функция всегда возвращаем противоположное значение (вместо true выдаёт false и наоборот), то есть используйте так:

stock getPlayerBugs(playerid)
{
    new pBugs = 0;
    for(new i = 0; i < MAX_BUGS; i++) {if(!strcmp(pData[playerid][pNickname],gBugDataName[i])) ++pBugs;}
    return pBugs;
}

[trevison Хороший 14]

сделал так, и ничего не исправилось

проблема осталась - всегда пишет что максимальное кол-во репортов

и я даже зашёл с аккаунта другого с не схожим ником со всеми

использую функцию так:

c:bug;
{
    if(pData[playerid][pMut]) return SendErr(playerid, "Вам заблокирован чат");
    if(pData[playerid][pRMut]) return SendErr(playerid, "Вам заблокирован чат");
    if(getPlayerBugs(playerid) >= 5) return SendErr(playerid, "У вас максимальное кол-во отправленных баг-репортов!");
    if(GetPVarInt(playerid,"BUGSLIST") > gettime() ) return SendErr(playerid, "Данная функция доступна раз в 3 минуты");
    ShowPlayerDialog(playerid, 7771, DIALOG_STYLE_INPUT, "Баг репорт", "{FFFFFF}Опишите баг кратко и ясно, строка ограничена 128 символами, постарайтесь вместить:", "Принять", "Закрыть");
    return 1;
}

если переделать с !strcmp на strcmp, то можно будет бесконечно отправлять баг-репорты

 

[Sleash Очень хороший 127]

1) Покажите как вы добавляете ник игрока в gBugDataName.

2) Почитайте про массивы, строки и их использования

[trevison Хороший 14]

создание баг-репорта:

new id = -1;
for(new i; i < MAX_BUGS; i++) if(!gBugDataName[i][0]) { id = i; break; }
if(id == -1) SendErr(playerid, "Баг репорт переполнен.");
new year, month, day, hour, minute, second, string[156];
getdate(year, month, day);
gettime(hour, minute, second);

GetPlayerName(playerid, gBugDataName[id], 25);
strmid(gBugDataText[id], inputtext, 0, strlen(inputtext), 128);
format(gBugDataDate[id], 20, "%i/%i/%i %i:%i:%i", year, month, day, hour, minute, second);

mysql_format(MySQLGo, string, 156, "INSERT INTO `bugs` (`id`, `name`, `text`, `date`, `status`) VALUES ('%i', '%e', '%e', '%e', '0')", id, gBugDataName[id], gBugDataText[id], gBugDataDate[id]);
mysql_tquery(MySQLGo, string);
gBugDataStatus[id] = 0;
SendSucc(playerid, "Благодарим вас за найденный баг.");
SendInf(playerid, "Используйте: /buginfo, чтобы посмотреть информацию о багах, которые вы сообщили.");

загрузка баг-листа:

new Cache:cache, rows;
cache = mysql_query(MySQLGo, "SELECT * FROM `bugs`"), rows = cache_num_rows();
if(rows)
{
    for(new i, id; i < rows; i++)
    {
        id = cache_get_field_content_int(i, "id");
        gBugDataStatus[id] = cache_get_field_content_int(i, "status");
        cache_get_field_content(i, "name", gBugDataName[id], 1, 25);
        cache_get_field_content(i, "text", gBugDataText[id], 1, 128);
        cache_get_field_content(i, "date", gBugDataDate[id], 1, 20);
    }
}
cache_delete(cache, MySQLGo);

 

[trevison Хороший 14]

заработало при этом коде

stock getPlayerBugs(playerid)
{
    new pBugs = 0;
    for(new i; i < MAX_BUGS; i++) if(gBugDataName[i][0]) if(!strcmp(gBugDataName[i],pData[playerid][pNickname])) ++pBugs;
    return pBugs;
}

через дебаг я понял, что ники не выводило вообще

и я повторил с функции отображения багов для игрока код и всё сработало)

Edited July 30 by trevison