[закрыто] Подтверждение действия

[NO2037 Хороший 1]

Здравствуйте. Как реализовать допустим подтверждения действия игрока. Допустим игрок №1 передал деньги другому игроку №2  и пока игрок №2 не нажмет к примеру кнопку "E" ему не передадутся деньги игрока №1. Наверное как-то через паблик OnPlayerKeyStateChange(). Можно пример пожалуйста? Не могу додумать))

[Sleash Очень хороший 139]

Спойлер

#if !defined PRESSED 
    #define PRESSED(%0) (((newkeys & (%0)) == (%0)) && ((oldkeys & (%0)) != (%0)))
#endif
CMD:pay(playerid, params[])
{
    new takeid, money;
    if(sscanf(params, "ud", takeid, money)) return SendClientMessage(playerid, -1, "/pay [ID] [money]");
    // проверка на валидность получателя
    // проверка на наличия суумы на руках
    // проверка на расстояние
    // проверка на лимиты
    // и ещё на Ваше усмотрение
    SetPVarInt(playerid, "pay_takeid", takeid);
    SetPVarInt(takeid, "pay_giveid", playerid);
    SetPVarInt(takeid, "pay_money", money);
    new plname[MAX_PLAYER_NAME]; GetPlayerName(playerid, plname, MAX_PLAYER_NAME);
    new str[145]; format(str, 145, "Игрок %s[%d] хочет передать вам деньги: $%d.", plname, playerid, money);
    SendClientMessage(takeid, -1, str);
    SendClientMessage(takeid, -1, "Нажмите \'Y\', что бы согласиться ИЛИ \'N\', что бы отказаться.");
    SendClientMessage(playerid, -1, "Ваше предложение о передаче денег успешно отправлено, что бы его отменить нажмите \'N\'.");
    return 1;
}
public OnPlayerKeyStateChange(playerid, newkeys, oldkeys)
{
    if (PRESSED(KEY_NO))
    {
        if(GetPVarInt(playerid, "pay_takeid")) {
            new takeid = GetPVarInt(playerid, "pay_takeid");
            DeletePVar(playerid, "pay_takeid");
            DeletePVar(takeid, "pay_giveid");
            DeletePVar(takeid, "pay_money");
            if(takeid != INVALID_PLAYER_ID && IsPlayerConnected(takeid)) {
                new plname[MAX_PLAYER_NAME]; GetPlayerName(playerid, plname, MAX_PLAYER_NAME);
                new str[145]; format(str, 145, "Игрок %s[%d] отменил передачу денег.", plname, playerid);
                SendClientMessage(takeid, -1, str);
            }
            return SendClientMessage(playerid, -1, "Вы успешно отказались от передачи денег");
        }
        if(GetPVarInt(playerid, "pay_giveid")) {
            new giveid = GetPVarInt(playerid, "pay_giveid");
            DeletePVar(giveid, "pay_takeid");
            DeletePVar(playerid, "pay_giveid");
            DeletePVar(playerid, "pay_money");
            if(giveid != INVALID_PLAYER_ID && IsPlayerConnected(giveid)) {
                new plname[MAX_PLAYER_NAME]; GetPlayerName(playerid, plname, MAX_PLAYER_NAME);
                new str[145]; format(str, 145, "Игрок %s[%d] отменил передачу денег.", plname, playerid);
                SendClientMessage(giveid, -1, str);
            }
            return SendClientMessage(playerid, -1, "Вы успешно отказались от передачи денег");
        }
    }
    if (PRESSED(KEY_YES))
    {
        if(GetPVarInt(playerid, "pay_giveid")) {
            new giveid = GetPVarInt(playerid, "pay_giveid");
            new money = GetPVarInt(playerid, "pay_money");
            DeletePVar(giveid, "pay_takeid");
            DeletePVar(playerid, "pay_giveid");
            DeletePVar(playerid, "pay_money");
            if(giveid != INVALID_PLAYER_ID && IsPlayerConnected(giveid)) {
                new plname[MAX_PLAYER_NAME]; GetPlayerName(playerid, plname, MAX_PLAYER_NAME);
                new str[145]; format(str, 145, "Игрок %s[%d] принял передачу денег.", plname, playerid);
                SendClientMessage(giveid, -1, str);
            }
            return SendClientMessage(playerid, -1, "Вы успешно приняли передачу денег");
            // Здесь код на добавление денег playerid на money
            // Здесь код на убавление денег giveid на money
        }
    }
    return 1;
}

 

Не тестил, но работать должно

[NO2037 Хороший 1]

@Sleash Сейчас нет возможности проверить. На глаз вроде бы то что нужно. Попробую завтра накидать. Если будут вопросы отпишу еще. Спасибо.

[NO2037 Хороший 1]

@Sleash Спасибо за идею. Переделал под себя конечно. Тему можно закрывать.

[NO2037 Хороший 1]

@Sleash Единственное в твоей примере не работает одно. Игрок №1 может передать деньги Игроку №2, а второй если передаст деньги Игроку №1 то уже не сможет Игрок №1 принять деньги.

[NO2037 Хороший 1]

@Sleash Там я потестил. Получается если ты нулевой ты не можешь передавать деньги PRESSED(KEY_YES) вообще не срабатывает, а если выше ID то вроде как получается. . Не знаю с чем связано.

Отредактировано 8 августа, 2023 пользователем NO2037

[NO2037 Хороший 1]

@Sleash Сейчас только допетрил кажется. Тут у нас false получается 

  if(GetPVarInt(playerid, "pay_giveid"))

если передает нулевое id то не срабатывает это условие

@Sleash В общем. Решилось все этой функцией GetPVarType(). Нужно было просто проверять на наличие переменной у игрока)

Спасибо за помощь.

Отредактировано 8 августа, 2023 пользователем NO2037