[Pawn] Генератор математических примеров

[142]

Всем доброго времени суток, сегодня я хочу Вам представить неоптимизированный из-за моей лени генератор математических примеров с ответами.
Без лишних слов перейдём к коду
Для начала нам надо добавить define для удобства использования:

#define skip:%0; {++%0;continue;}

Куда вы его поместите - дело Ваше, но желательно в начало мода. Тоже самое с функцией, преобразующей число в строку:

stock intToStr(a) {new asd[8]; format(asd, 8, "%d", a); return asd;}

Теперь же давайте рассмотрим код самого генератора. Он умещён в одну функцию, очень длинную функцию:

Спойлер

stock CreateCase(strCase[], actions = 3, max_ints = 350, strSize = 128) {
    new answer = 0; ++actions;
    for(new i = actions; i > 0; i--) {
        new plussing = 1, rnd_act = random(101);
        if(60 <= rnd_act <= 80) {
            new Fint = random(max_ints/15);
            if(!Fint) skip:i;
            if(i != actions) {
                if(i < 2) skip:i; else i--;
                if(random(2)) strcat(strCase, "+", strSize);
                else strcat(strCase, "-", strSize), plussing = -1;
            }
            new Sint = max_ints/Fint;
            if(random(2)) strcat(strCase, intToStr(Fint), strSize), strcat(strCase, "*", strSize), answer += Fint*Sint*plussing;
            else strcat(strCase, intToStr(Fint*Sint), strSize), strcat(strCase, "/", strSize), answer += (Fint*Sint/Sint)*plussing;
            strcat(strCase, intToStr(Sint), strSize);
        } else if (80 < rnd_act <= 100) {
            if(i != actions) {
                if(i < 4) skip:i; else i--;
                if(random(2)) strcat(strCase, "+", strSize);
                else strcat(strCase, "-", strSize), plussing = -1;
            } if(i < 3) skip:i;
            new rnd_brac = random(i-2)+1;
            i -= rnd_brac;
            new strCaseBrackets[64]; new BrackAns = CreateCase(strCaseBrackets, rnd_brac, max_ints, 64);
            answer += BrackAns*plussing;
            strcat(strCase, "(", strSize); strcat(strCase, strCaseBrackets, strSize); strcat(strCase, ")", strSize);
        } else if(0 <= rnd_act <= 15) {
                new Fint = random(4)+1;
                if(i != actions) {
                    if(i < 2) skip:i; else i--;
                    if(random(2)) strcat(strCase, "+", strSize);
                    else strcat(strCase, "-", strSize), plussing = -1;
                }
                new Float:fSint = floatlog(max_ints*1.0, Fint*1.0);
                new Sint = floatround(fSint, floatround_ceil);
                strcat(strCase, intToStr(Sint), strSize);
                strcat(strCase, "^", strSize), answer += floatround(floatpower(Sint, Fint))*plussing;
                strcat(strCase, intToStr(Fint), strSize);
        } else {
            if(i != actions) {
                if(random(2)) strcat(strCase, "+", strSize);
                else strcat(strCase, "-", strSize), plussing = -1;
            }
            new intt = random(max_ints/2);
            strcat(strCase, intToStr(intt), strSize);
            answer += intt*plussing;
        }
    }
    return answer;
}

 

Чуть позже рассмотрим пример использования генератора, а сейчас разберёмся с параметрами:
strCase - строка, в которую запишется пример;
actions - количество действий в примере (Иногда генератор может вписывать на 1 действие больше)
max_ints - число, которое будет использоваться как максимум в отдельных действиях

Т. е. вычитаемое, слогамое, делимое, произведение и результат возведения в степень не будет больше max_ints

strSize - размер строки strCase. Так как в функциях невозможно определить размер через sizeof, а при strlen нельзя будет добавить числа, то я решил использовать эту пеерменную

Теперь само использование функции:

Спойлер

 

...(...) {  
    for(new i = 0; i < 10; i++) {                       // Цикл генерации 10-и примеров
        printf("-------------№%d------------", i+1);    // разделение примеров для удобного обозрения
        new strr[128];                                  // переменная для хранения примера
        new ans;                                        // переменная для хранения ответа
        ans = CreateCase(strr, 5, 350);                 // генерация примера и запись ответа
        printf("Case: %s", strr);                       // вывод примера
        printf("Answer: %d", ans);                      // вывод ответа
        printf("Real actions: %d", ChechActs(strr));    // вывод реального количества действий
    }
    ...
}
stock ChechActs(const str[]) {
    new acts = 0;
    for(new i = 0; i < strlen(str); i++) {
        switch(str[i]) {
            case '-','/','*','+','^': ++acts;
        }
    }
    return acts;
}

Внимание: В некоторых случаях может возникать следующе предупреждение в консоли:

[debug] Long callback execution detected (hang or performance issue)

Данное сообщение свидетельствует о том, что код долго выполняется, скорее всего из-за плохой оптимизации)

Назовём это ложкой дёгтя в бочке мёда)
После генерации 10-и примеров в консоли мы увидим следующее:

Спойлер

Любой из примеров вы можете вбить в калькулятор и он выдаст тот же ответ, что и написан в консоли.
Этот генератор можно использовать в качестве проверки на бота или интерактива. Пример:

Спойлер

 

new tempAnswer;
forward CreateICCase();
public CreateICCase() {
    new tempCase[128];
    tempAnswer = CreateCase(tempCase, 3, 150);
    SendClientMessageToAll(-1, "Введите ответ на следующий пример в /cans и получите приз:");
    SendClientMessageToAll(-1, tempCase);
}
public OnGameModeInit() {
    SetTimer("CreateICCase", 1000*60*30, true);
}
CMD:cans(playerid, params[]) {
    if(sscanf(params, "d", params[0])) return false;
    if(params[0] == tempAnswer) GivePlayerMoney(playerid, 5000);
    else SendClientMessage(playerid, -1, "Неверный ответ");
    return 1;
}

Код выше далёк от того, который можно было бы использовать, как минимум потому, что нет ограничение на то, сколько раз давать ответ, но именно поэтому это и является всего лишь вводным примером.
А на этом я бы хотел закончить представление генератора примеров, всем спасибо за чтение!
UPDATE:
Забыл упомянуть, не стоит привязывать к такому интерактиву большие призы, так как написать Lua-скрипт, который решит такой пример довольно просто (знаю по себе, ибо сам такой же и писал)

Отредактировано 16 декабря, 2023 пользователем Sleash