[закрыто] Вывод ника по тегу

[2]

Здравствуйте. Как сделать, допустим, игрок в чат отправил символ # и рядом указал цифру допустим так: #0 (ноль id игрока на сервере) и в ответ вывелось ему ник игрока, который под этим ID. Нужно как то я думаю искать символ # через strfind, а дальше цифру как проверить? Или как то через sscanf?

Отредактировано 2 августа, 2024 пользователем NO2037

[14]

в начало onplayertext, playername меняешь на свою переменную имени

 

    new atSymbolPos = strfind(text, "@"),
        spacePos = -1,
        bool:isValid = true;

    if(atSymbolPos != -1)
    {
        for(new i = atSymbolPos; i != strlen(text); i++)
        {
            switch(text[i])
            {
                case 48..57: continue;
                case 32, EOS:
                {
                    spacePos = i;
                    break;
                }
                default:
                {
                    isValid = false;
                    break;
                }
            }
        }

        if(spacePos - atSymbolPos == 0) isValid = false;
        if(spacePos - atSymbolPos >= 4) isValid = false;

        if(isValid == true)
        {
            new targetid,
                targetidString[5];
            strmid(targetidString, text, atSymbolPos + 1, spacePos);

            targetid = strval(targetidString);

            if(targetid != INVALID_PLAYER_ID && IsPlayerConnected(targetid))
            {
                strdel(text, atSymbolPos, spacePos);
                strins(text, playername(targetid), atSymbolPos, 144);
            }
        }
    }

 

[2]

@ddrgtagfon А если попроще что-нибудь?

Отредактировано 2 августа, 2024 пользователем NO2037

[14]

@NO2037 ну заюзай инклуд Mentions от AbyssMorgan или же заюзай вариант от tommyled с sscanf
 

public OnPlayerText(playerid, text[])
{
    new 
        PlayerName[MAX_PLAYER_NAME + 1],
        Message[MAX_CHATBUBBLE_LENGTH],
        tag_string[2][MAX_CHATBUBBLE_LENGTH - MAX_PLAYER_NAME * 2 - 12],
        targetid;

    GetPlayerName(playerid, PlayerName, sizeof PlayerName);

    if(!sscanf(text, "P<*@>s[*]s[*]", sizeof tag_string[], tag_string[0], sizeof tag_string[], tag_string[1]) && !sscanf(tag_string[1], "U(i)s[*]", targetid, sizeof tag_string[], tag_string[1]) && IsPlayerConnected(targetid) && targetid != playerid)
    {
        new
            TargetName[MAX_PLAYER_NAME + 1];

        GetPlayerName(targetid, TargetName, sizeof TargetName);
        if(!strlen(tag_string[0])) format(Message, sizeof Message, "%s[%d]: "CODE_RED"%s"CODE_WHITE" %s", PlayerName, playerid, TargetName, tag_string[1]);
        else format(Message, sizeof Message, "%s[%d]: %s "CODE_RED"%s"CODE_WHITE" %s", PlayerName, playerid, tag_string[0], TargetName, tag_string[1]);
    }
    else format(Message, sizeof Message, "%s[%d]: %s", PlayerName, playerid, text);
    SendClientMessageToAll(-1, Message);
    return false;
}